Utilizar serpro com proxy

ticonsil

Problema com o Serpro e Proxy após atualização (.bat → .exe)

Em 2023 foi aberto alguns tópicos sobre a utilização do Serpro com proxy, onde foi descoberta a solução.
Porém, recentemente em 2025, houve uma atualização que trocou o Serpro de .bat para .exe, e por causa disso a solução antiga não resolve mais.

Antes utilizávamos o seguinte script no PowerShell:

(Get-Content 'C:\Program Files (x86)\Assinador Serpro\signerDesktopAgent.bat') -replace '-Djava.net.useSystemProxies=true', '-Djava.net.useSystemProxies=false' | Set-Content 'C:\Program Files (x86)\Assinador Serpro\signerDesktopAgent.bat'

Porém, como agora o programa é um .exe, não é possível fazer essa modificação diretamente.

Também tentei editar o arquivo:

C:\Program Files (x86)\Assinador Serpro\java\lib\net.properties

E deixei as seguintes configurações:

java.net.useSystemProxies=false
http.nonProxyHosts=localhost|127.*|[::1]
https.nonProxyHosts=localhost|127.*|[::1]|*.local

Mas mesmo assim o sistema não abre.

Alguém com o mesmo problema? Pelo que vi, a versão não mudou, apenas o método de abertura.

ticonsil

Consegui com o comando abaixo, não é o ideal mas da pro gasto, se alguém tiver alguma solução melhor vamos compartilhar o conhecimento.

@echo off
REM Assinador Serpro - Launcher sem uso de proxy do sistema
REM Funciona em qualquer usuário (usa variáveis de ambiente)

REM Caminho base de instalação (Program Files (x86))
set "BASE=%ProgramFiles(x86)%\Assinador Serpro"
set "JAVA_EXE=%BASE%\java\bin\javaw.exe"
set "JAVA_LIB_PATH=%BASE%"
set "CP=%BASE%\lib\serpro-signer-4.3.2.jar;%BASE%\lib\plugins\*"

REM Temp dinâmico a partir do usuário
set "TMPDIR=%LOCALAPPDATA%\Temp"

REM Verifica se java existe
if not exist "%JAVA_EXE%" (
    echo Erro: javaw.exe nao encontrado em "%JAVA_EXE%"
    pause
    exit /b 1
)

REM Monta e executa o comando Java
start "" /B "%JAVA_EXE%" -Xms256m -Xmx4096m -XX:MinHeapFreeRatio=20 -XX:MaxHeapFreeRatio=40 ^
 -Dfile.encoding=UTF-8 ^
 -Duser.timezone=GMT-3 ^
 -Djava.io.tmpdir="%TMPDIR%" ^
 -Djava.library.path="%JAVA_LIB_PATH%" ^
 -Djava.net.useSystemProxies=false ^
 -cp "%CP%" ^
 org.demoiselle.signer.serpro.desktop.Main

exit

Só montar em um .bat e abrir, a tela vai fechar rapidamente e dentro de 10 segundos ele abre o serpro.